Últimos mensajes - Powered by IBM

Palabras claves

Formula

05/01/2005 - 17:37 por Angelo | Informe spam

Buenos Días,

Mi problemita es que tengo que hacer un calculo de un impuesto segun una
tabla, parte de la tabla es esta formula que muestro a continuación:

=SUMA(SI((G6>3000)*(G6<3250),(G6-3000)*52%,0),SI((G6>3250)*(G6<4000),((G6-3250)*4%)+130,0),SI((G6>4000)*(G6<6000),((G6-4000)*6.5%)+160,0),SI((G6>6000)*(G6<10000),((G6-6000)*11%)+290,0),SI((G6>10000)*(G6<15000),((G6-10000)*16.5%)+730,0),SI((G6>15000)*(G6<20000),((G6-15000)*19%)+1555,0),SI((G6>20000)*(G6<30000),((G6-20000)*22%)+2505,0),SI((G6>30000)*(G6<40000),((G6-30000)*27%)+4705,0),SI((G6>40000)*(G6<50000),((G6-40000)*30%)+7405,0),SI((G6>50000)*(G6<200000),((G6-50000)*33%)+10405,0))

Entonces tengo en la celda G1 el valor Mensual y la G6 el valor Anual, segun
la ley tengo lo siguiente el ingreso anual hasta 10400 no paga impuesto oseas
que si yo ponco en en valor de la celda G1 un valor igual o menor a 800 no
lleva ningun impuesto osea que es igual a cero, pero si el valor es entre
801y 859 mensual todo lo que este entre ese rango es impuesto, osea que
tampoco usaria la tabla de arriba solo tomaria si es 825 el impuesto sería
25.00. Esta es una Parte,

La otra parte seria para hacerlo anualmente, anualmente el rango es 10,401 a
11,167 osesa que si tengo 10,750 mi impuesto seria 350, pero despues que pase
de 11,167 tengo que tomar la tabla de arriba mencionada y si es igual o menor
a 10,401 mi impuesto seria cero.

Espero haberme explicado y que me puedan ayudar con esto.

Saludos,
Angelo.!

Siga el debate

7 respuestas

Tengo una respuesta

Preguntas similare

Mostrar todos los temas similares

Leer las respuestas

#1 Héctor Miguel

06/01/2005 - 03:49 | Informe spam

hola, Angelo !

... tengo que hacer un calculo de un impuesto segun una tabla, parte de la tabla es esta formula [...]

creo que te conviene mejor elaborar una tabla 'real' [en lugar de usar formulas laaaargas]
es mas facil hacer modificaciones/actualizaciones sin 'tener que' re-hacer varios calculos.

suponiendo que te decides por usar la tabla 'real' [p.e. en el rango 'A2:A12' sin incluir los titulos]
te pongo unas formulas 'de ejemplo' al final, usando indice() y coincidir()
[podrias tambien usar la funcion buscarv() o algunas otras mas]

saludos,
hector.
la tabla ==L. Inf. L. Sup. C. F. % / Exc.
$0 $3,000
$3,001 $3,250 2.0%
$3,251 $4,000 $130 4.0%
$4,001 $6,000 $160 6.5%
$6,001 $10,000 $290 11.0%
$10,001 $15,000 $730 16.5%
$15,001 $20,000 $1,555 19.0%
$20,001 $30,000 $2,505 22.0%
$30,001 $40,000 $4,705 27.0%
$40,001 $50,000 $7,405 30.0%
$50,001 y mas... $10,405 33.0%

[G6] -> el sueldo para calcular el impuesto

una formula para 'descontar' el L.Inf, aplicar el %/Exc y sumar la C.F. = total_del_impuesto
=(g6-indice(a2:a12,coincidir(g6,a2:a12)))*indice(d2:d12,coincidir(g6,a2:a12))+indice(c2:c12,coincidir(g6,a2:a12))

o podrias 'recortarla' si usas una celda 'puente' para obtener la posicion del L.Inf en la tabla...
[G7] =coincidir(g6,a2:a12)
[G8] =(g6-indice(a2:a12,g7))*indice(d2:d12,g7)+indice(c2:c12,g7)

Responder a este mensaje

#2 KL

06/01/2005 - 10:19 | Informe spam

Hola HM,

"Héctor Miguel" wrote in message...

la tabla ==> L. Inf. L. Sup. C. F. % / Exc.
$0 $3,000
$3,001 $3,250 2.0%
$3,251 $4,000 $130 4.0%
$4,001 $6,000 $160 6.5%
$6,001 $10,000 $290 11.0%
$10,001 $15,000 $730 16.5%
$15,001 $20,000 $1,555 19.0%
$20,001 $30,000 $2,505 22.0%
$30,001 $40,000 $4,705 27.0%
$40,001 $50,000 $7,405 30.0%
$50,001 y mas... $10,405 33.0%

[G6] -> el sueldo para calcular el impuesto

una formula para 'descontar' el L.Inf, aplicar el %/Exc y sumar la C.F. =
total_del_impuesto
=(g6-indice(a2:a12,coincidir(g6,a2:a12)))*indice(d2:d12,coincidir(g6,a2:a12))+indice(c2:c12,coincidir(g6,a2:a12))

o podrias 'recortarla' si usas una celda 'puente' para obtener la posicion
del L.Inf en la tabla...
[G7] =coincidir(g6,a2:a12)
[G8] =(g6-indice(a2:a12,g7))*indice(d2:d12,g7)+indice(c2:c12,g7)

Si descontamos L.Inf de la base imponible entonces tambien descontamos el
dolar q deberia tener una retencion mas alta, p.ej:
[G6] E00
[G7] =4
[G8] =(4500-4001)*6.5%+160= 192.435
-

?no crees q deberiamos descontar la base superior del rango anterior? o sea:
[G8] =(4500-4000)*6.5%+160= 192.5

si estas de acuerdo, creo q los cambios a tu solucion podrian ser los
siguientes:

1. Mover los datos de la segunda columna de la matriz una fila mas abajo:

L. Inf. L. Sup. C. F. % / Exc.
$0
$3,001 $3,000 2.0%
$3,251 $4,250 $130 4.0%
$4,001 $4,000 $160 6.5%
$6,001 $6,000 $290 11.0%
etc.

2. modificar la formula final:
[G7] =COINCIDIR(G6,A2:A12)
[G8] =(G6-INDICE(B2:B12,G7))*INDICE(D2:D12,G7)+INDICE(C2:C12,G7)

la otra forma, como bien has dicho podria ser la de BUSCARV():
[G8] =(G6-BUSCARV(G6,A2:D12,2))*BUSCARV(G6,A2:D12,4)+BUSCARV(G6,A2:D12,3)

o poniendole un nombre a la matriz, digamos "TBL"¢:D12
[G8] =(G6-BUSCARV(G6,TBL,2))*BUSCARV(G6,TBL,4)+BUSCARV(G6,TBL,3)

?comentas?

Saludos,
KL

Responder a este mensaje

#3 Héctor Miguel

06/01/2005 - 10:50 | Informe spam

hola, KL !

Si descontamos L.Inf de la base ... tambien descontamos el dolar q deberia tener una retencion mas alta [...]

en realidad, creo recordar que los 'saltos' no van por 'enteros' [$1] sin por centesimas [$0.01]
con lo cual, la 'diferencia' deja de ser 'significativa'
[solo trate de no 'llenar el cuadro' con algun exceso de $.00]
por consiguiente... tienes razon ;) [y... yo no debi 'ahorrar' el espacio] :(

saludos,
hector.

Responder a este mensaje

#4 KL

06/01/2005 - 11:08 | Informe spam

"Héctor Miguel" ...

en realidad, creo recordar que los 'saltos' no van por 'enteros' [$1] sin
por centesimas [$0.01]

Bueno, eso si q segun en q pais. Dirigo Compensacion y Beneficios de mi
empresa en 38 paises europeos y hay de todo, pero teoricamente tienes razon.
Por lo cual creo q podriamos hasta eliminar la primera columna ya q,
siguiendo con mi ejemplo anterior, si la base imponible es de 4000, la
formula hara esto 0*6.5%+160 y si es 4000.01 entonces 0.01*6.5%+160 y
quedamos a pre con la agencia tributaria :-)

con lo cual, la 'diferencia' deja de ser 'significativa'

Mucho ojo con la hacienda, eh!!! Casi siempre es mejor pagar un poco mas q
menos :-)

Saludos,
KL

Responder a este mensaje

#5 Angelo

06/01/2005 - 14:03 | Informe spam

Holas, gracias por su ayuda, voy a probar las formulas a ver que pasa
despues les comento

"KL" escribió:

"Héctor Miguel" ...

> en realidad, creo recordar que los 'saltos' no van por 'enteros' [$1] sin
> por centesimas [$0.01]

Bueno, eso si q segun en q pais. Dirigo Compensacion y Beneficios de mi
empresa en 38 paises europeos y hay de todo, pero teoricamente tienes razon.
Por lo cual creo q podriamos hasta eliminar la primera columna ya q,
siguiendo con mi ejemplo anterior, si la base imponible es de 4000, la
formula hara esto 0*6.5%+160 y si es 4000.01 entonces 0.01*6.5%+160 y
quedamos a pre con la agencia tributaria :-)

> con lo cual, la 'diferencia' deja de ser 'significativa'

Mucho ojo con la hacienda, eh!!! Casi siempre es mejor pagar un poco mas q
menos :-)

Saludos,
KL

Responder a este mensaje

Ads by Google

Hacer una preguntaSiguiente

Tengo una respuesta

Busqueda sugerida