VBA Excel: Mover entre pestañas filas que cumplan ciertas características

... Tengo una pestana en la cual tengo una matriz muy grande.
Cada linea pertenece a un individuo distinto, y en la cabecera de la matriz (esto es, en la primera fila de la matriz) aparecen los titulos.
Imaginemos que los titulos son: Nombre, Edad, Poblacion.
Lo que quiero es que los individuos que cumplan la condición de Edad = 30
(esto es, que en la linea de dicho individuo aparezca el numero 30 en la celda de la columna Edad)
se borren de la matriz original y se copien en otra pestana que se llama Edad_30.
Dicha pestana Edad_30 ya tiene copiada en ella el cabecero de la original (Nombre, Edad, Poblacion).
Para afrontar el problema de forma manual suelo aplicar filtros automaticos en la cabecera de la matriz original
filtro los de Edad = 30 y luego corto la matriz resultante y la pego en la pestana Edad_30.
No he podido automatizar esto ya que en cada matriz de datos el primer elemento que cumple la caracteristica esta una linea distinta.
Sabeis como se puede automatizar el proceso, ya sea con autofiltros o con otro sistema?

hola, Alex !

"imaginemos" que trabajas sobre la "hoja activa" y que el listado se inicia en la celda [A1]
"imaginamos" que el cabecero de "Edad" se encuentra en la celda [B1] (esto es, el segundo elemento de filtros)

te serviria una macro +/- como la siguiente:

Sub Mover_a_Otra_hoja()
  Dim Edad As Byte
  Edad = 30
  Application.ScreenUpdating = False
  With ActiveSheet
    If Application.CountIf(Range("b:b"), Edad) Then
      .Range("a1").AutoFilter 2, Edad
      With .AutoFilter.Range
        With .Offset(1).Resize(.Rows.Count - 1)
          .Copy Worksheets("edad_" & Edad).Range("a65536").End(xlUp).Offset(1)
          .EntireRow.Delete
        End With
      End With
      .AutoFilterMode = False
    Else
      MsgBox "No existen elementos de: " & Edad
    End If
  End With
End Sub

si cualquier duda (o informacion adiiconal)... comentas ?
saludos,
hector.

__ OP __

... En la hoja de datos original, antes de extraer... dichos cabeceros ya estan con el autofiltro aplicado ...
... debere extraer alguno mas, pero al aplictar tu macro, despues de extraer... ya no hay autofiltros, con lo cual debo volvera a aplicarlos.
Se que podría volver a añadirlos con sencillo codigo:

Sheets("Edad_30").Select
Rows("1:1").Select
Selection.AutoFilter

pero me gustaria saber si podría hacer que al terminar tu macro los autofiltros perdurasen
en vez de metiendo mas codigo y por tanto dificultando el entendimiento
quitandolo (quitar las líneas de tu codigo que quitan el autofiltro de las cabeceras despues de la extraccion) ...

hola, Alex !

1) no se si preguntas por poner/preservar/.. autofiltros en la hoja "original" y/o tambien en la/s hoja/s de resumen    -?-
    - si las hojas de resumen tienen autofiltros, el codigo propuesto ni siquiera "los toca", por lo que deberan preservarse

2) los autofiltros en la hoja "original", crei entender que solo eran necesarios para la extraccion de la edad solicitada a "su resumen"
    por lo que pensaba en aplicar un inputbox para que el usuario provea el numero (edad) de la que requiere su extraccion    -?-
    (que ademas le daria mayor "flexibilidad" al uso de una sola macro y no una por cada edad)    ;)

3) si prefieres mantener los autofiltros en la hoja "original", solo cambia estas instrucciones:

de:
      End With
      .AutoFilterMode = False
    Else

  a:
      End With
      .Range("a1").AutoFilter 2
    Else

si cualquier duda (o informacion adicional)... comentas ?
saludos,
hector.

__ OP __