Sacar una caracter de una cadena

"Cesar" escribió en el mensaje news:0e1301c4e45f$cfeba710$

Como puedo sacar un caracter de una cadena en base a
alguna funcion?

por ejemplo:

Tengo un nombre

"ALEJANDRO" y quiero sacar la primera consonante de esa
palabra, en este caso "L"

Función, que yo sepa, no la hay (aunque se podría escribir una), pero puedes usar la siguiente fórmula

=EXTRAE(A1;COINCIDIR(0;ESERROR(ENCONTRAR(EXTRAE(A1;FILA(INDIRECTO("1:"&LARGO(A1)));1);"BCDFGHJKLMNÑPQRSTVWXYZ"))*1;0);1)

teniendo en cuenta que:
- es matricial (tienes que introducirla pulsando Mayúsculas+Control+Entrada al mismo tiempo)
- quizás tengas que sustituir los puntos y coma por comas, dependiendo de la configuración regional de tu equipo
- el texto a analizar se encuentra en la celda A1
- dicho texto está en mayúsculas
- si no hubiera ninguna consonante en el texto, la fórmula devolvería el error #N/A

Un saludo.


Fernando Arroyo
MS MVP - Excel

Ok funciona pero como lo haria para la segunda consonante

Cesar,

Prueba esta formula tambien matricial (cambia el 5 al final de la formula
por el numero de consonante q quires extraer, p.ej. primera -1, segunda-2,
etc.):

=EXTRAE(A1,K.ESIMO.MENOR(SI(ESERROR(ENCONTRAR(EXTRAE("BCDFGHJKLMNÑPQRSTVWXZ",FILA(INDIRECTO("1:21")),1),A1)),"",ENCONTRAR(EXTRAE("BCDFGHJKLMNÑPQRSTVWXZ",FILA(INDIRECTO("1:21")),1),A1)),5),1)

Ojo-> es posible q en la version espanola no funcione por su longitud, la
version inglesa (abajo) me funciona, pero esta cerca del limite.

=MID(A1,SMALL(IF(ISERROR(FIND(MID("BCDFGHJKLMNÑPQRSTVWXZ",ROW(INDIRECT("1:21")),1),A1)),"",FIND(MID("BCDFGHJKLMNÑPQRSTVWXZ",ROW(INDIRECT("1:21")),1),A1)),2),1)

La otra forma de hacerlo q se me ocurre es esta formula no matricial (cambia
el 2 por el numero de la consonante a extraer):

=EXTRAE(SUSTITUIR(A1,{"A","O","U","E","I","Y"},""),2,1)

El problema de esta formula es q tendras q prever todos los posibles
caracteres q no sean consonantes y q puedan aparecer en tu texto, pero si
solo se utilizan letras debera servirte .

Saludos,
KL

"Cesar" wrote in message
news:044201c4e467$69936bd0$

Ok funciona pero como lo haria para la segunda consonante

Una correccion - la ultima formula no funciona poque no sustituye todas la
letras a la vez, sino uno por una, o sea si la palabra es "PALO", devuelve
la siguiente matriz {"PLO","PAL","PALO","PALO","PALO","PALO"}

KL

"KL" <lapink2000(at)hotmail.com> wrote in message
news:

Cesar,

Prueba esta formula tambien matricial (cambia el 5 al final de la formula
por el numero de consonante q quires extraer, p.ej. primera -1, segunda-2,
etc.):

=EXTRAE(A1,K.ESIMO.MENOR(SI(ESERROR(ENCONTRAR(EXTRAE("BCDFGHJKLMNÑPQRSTVWXZ",FILA(INDIRECTO("1:21")),1),A1)),"",ENCONTRAR(EXTRAE("BCDFGHJKLMNÑPQRSTVWXZ",FILA(INDIRECTO("1:21")),1),A1)),5),1)

Ojo-> es posible q en la version espanola no funcione por su longitud, la
version inglesa (abajo) me funciona, pero esta cerca del limite.

=MID(A1,SMALL(IF(ISERROR(FIND(MID("BCDFGHJKLMNÑPQRSTVWXZ",ROW(INDIRECT("1:21")),1),A1)),"",FIND(MID("BCDFGHJKLMNÑPQRSTVWXZ",ROW(INDIRECT("1:21")),1),A1)),2),1)

La otra forma de hacerlo q se me ocurre es esta formula no matricial
(cambia el 2 por el numero de la consonante a extraer):

=EXTRAE(SUSTITUIR(A1,{"A","O","U","E","I","Y"},""),2,1)

El problema de esta formula es q tendras q prever todos los posibles
caracteres q no sean consonantes y q puedan aparecer en tu texto, pero si
solo se utilizan letras debera servirte .

Saludos,
KL

"Cesar" wrote in message
news:044201c4e467$69936bd0$

Ok funciona pero como lo haria para la segunda consonante