listas u opciones desplegables

hola, !

Tengo para elegir que producto poner en una celda,
marca A, 3 productos, cada producto su precio
marca B, 5 productos, cada producto se precio
Existe alguna forma de elegir el producto que busco, como en internet se elige ver/barra de erramientas/dibujo
y en este caso dibujo aparesca en la celda selecionada, algo asi como un menu desplegable
algo mas avanzado que las listas de validacion
alguna sugerencia, en excel o con otro programa para hacer la selecion mas virtual o desplegandose ??????

(hasta donde se) el uso de listas de validacion puede ser tan "avanzado" (o complicado) como...
- la claridad en los detalles con que expongas "tu situacion" (que, como, cuando, de donde, a donde, etc.)
- tus habilidades para determnar sus dependencias (que sucede cuando se cambia una seleccion previamente hecha)
- causa, razon, motivo o circunstancia por las que consideras las listas de validacion "insuficientes" (que has intentado ?)
- etc. etc. etc.

si cualquier duda (o informacion adicional)... comentas ?
saludos,
hector.

Hola para realizar la selecion del ultimo producto o el deseado tengo que
implantar 3 pestañas desplegables o de validacion y por lo menos trees
celdas, lo que busco hacerlo todo en una celda ...

una clave general o de producto, no me ayuda

me es mas practico posicionarme en una celda, aparescan 2 marcas a elegir,si
eligo la marca A, aparesca una flecha a su derecha que al pocisionarme me
desplige otra lista con los tres productos que comprende esa marca. comoel
menu principal de internet,

hola, !

lo que buscas, se parece mas a un menu contextual (commandbars/popup) usando macros/vba
que podria funcionar sin mayores complicaciones en las versiones 97/2003
y (probablemente) con mas poquitin de mas "trabajo" tambien para la version 2007

si tienes dudas (o informacion adicional)... comentas ?
saludos,
hector.

__ OP __

... para realizar la selecion del ultimo producto... tengo que implantar 3... desplegables o de validacion
y por lo menos trees celdas, lo que busco hacerlo todo en una celda ...
una clave general o de producto, no me ayuda
me es mas practico posicionarme en una celda, aparescan 2 marcas a elegir
si eligo la marca A, aparesca una flecha a su derecha
que al pocisionarme me desplige otra lista con los tres productos que comprende esa marca
como el menu principal de internet.

creo que no conosco nada de los menu contextuales, algunos ejemplos o como
usarlas? PLS

hola, !

creo que no conosco nada de los menu contextuales, algunos ejemplos o como usarlas? PLS

lo siguiente (y solo a manera de ejemplo, para las versiones 97 / 2003):

- agrega dos "menus" cada uno con tres "opciones" al menu contextual que aparece al hacer clic-derecho sobre una celda
y a cada (sub)menu le agrega tres botones
NOTA que al asignar la propiedad .OnAction se utiizan apostrofes para delimitar la macro y el argumento <= OJO

- segun la opcion (del menu correspondiente) llama a una de dos macros y le "pasa" un parametro para que la macro "responda"
(deposita en la celda activa la accion correspondiente segun el comando del menu seleccioado)

- al salir/cerrar ese libro, restablece el menu contextual a su estado original (OJO por si tuvieras "peronalizado" ese menu)

plis: revisa, analiza, prueba, modifica/adapta... (lo que sea necesario)

si cualquier duda (o informacion adicional)... comentas ?
saludos,
hector.

copia/pega las siguientes instrucciones:

1) en el modulo de codigo de tu libro (ThisWorkbook)

Private Sub Workbook_Open()
Agrega_miMenu
End Sub
Private Sub Workbook_BeforeClose(Cancel As Boolean)
Quita_miMenu
End Sub

2) en un modulo de codigo estandar/general/normal (en el mismo libro)

Option Private Module
Sub Quita_miMenu()
On Error Resume Next
Application.CommandBars("cell").Reset
End Sub
Sub Agrega_miMenu()
With Application.CommandBars("cell")
With .Controls.Add(Type:=msoControlPopup, Temporary:=True)
.Caption = "Opciones del grupo &A"
With .Controls.Add(Type:=msoControlButton, Temporary:=True)
.Caption = "Grupo A, Opcion &1"
.OnAction = "'OpcionesGrupoA 1'"
End With
With .Controls.Add(Type:=msoControlButton, Temporary:=True)
.Caption = "Grupo A, Opcion &2"
.OnAction = "'OpcionesGrupoA 2'"
End With
With .Controls.Add(Type:=msoControlButton, Temporary:=True)
.Caption = "Grupo A, Opcion &3"
.OnAction = "'OpcionesGrupoA 3'"
End With
End With
With .Controls.Add(Type:=msoControlPopup, Temporary:=True)
.Caption = "Opciones del grupo &B"
With .Controls.Add(Type:=msoControlButton, Temporary:=True)
.Caption = "Grupo B, Opcion &1"
.OnAction = "'OpcionesGrupoB 1'"
End With
With .Controls.Add(Type:=msoControlButton, Temporary:=True)
.Caption = "Grupo B, Opcion &2"
.OnAction = "'OpcionesGrupoB 2'"
End With
With .Controls.Add(Type:=msoControlButton, Temporary:=True)
.Caption = "Grupo B, Opcion &3"
.OnAction = "'OpcionesGrupoB 3'"
End With
End With
End With
End Sub
Sub OpcionesGrupoA(Opcion As Byte)
Select Case Opcion
Case 1: ActiveCell = "Opcion 1 del Grupo A"
Case 2: ActiveCell = "Opcion 2 del Grupo A"
Case 3: ActiveCell = "Opcion 3 del Grupo A"
End Select
End Sub
Sub OpcionesGrupoB(Opcion As Byte)
Select Case Opcion
Case 1: ActiveCell = "Opcion 1 del Grupo B"
Case 2: ActiveCell = "Opcion 2 del Grupo B"
Case 3: ActiveCell = "Opcion 3 del Grupo B"
End Select
End Sub