Formula De Promedio - Urgente

Prueba esta formula suponiendo que el ragno de número que quieres el
promedio es B6:b25

=(SUMA(B6:B25)-MAX(B6:B25)-MIN(B6:B25))/(CONTAR.SI(B6:B25,">0")-2)

Angelo Vernaza

"Ricardo Castillo" escribió en
el mensaje news:

Por favor necesito una forma de promedio que exonere los valores minimo y
maximo de un rango mer podran ayudar

Creo que, en el caso de que en el rango hubiese numeros negativos, seria
mejor:

=(SUMA(B6:B25)-MAX(B6:B25)-MIN(B6:B25))/(CONTAR(B6:B25)-2)


Toni.
CAT.

*******************

Prueba esta formula suponiendo que el ragno de número que quieres el
promedio es B6:b25

=(SUMA(B6:B25)-MAX(B6:B25)-MIN(B6:B25))/(CONTAR.SI(B6:B25,">0")-2)

Angelo Vernaza

"Ricardo Castillo" escribió en
el mensaje news:

Por favor necesito una forma de promedio que exonere los valores minimo y
maximo de un rango mer podran ayudar

Hola chicos,

"Angelo Vernaza" wrote

=(SUMA(B6:B25)-MAX(B6:B25)-MIN(B6:B25))/(CONTAR.SI(B6:B25,">0")-2)

1) Si se trata de excluir solo una instancia de MIN y MAX, entonces probad
la siguiente formula:

=MEDIA.ACOTADA(A1:A10,2/CONTAR(A1:A10))

2) Si, en cambio, hay que excluir todas las instancias de MIN y MAX,
entonces:

=(SUMAR.SI(A1:A10;"<>"&MAX(A1:A10))-SUMAR.SI(A1:A10;MIN(A1:A10)))/(CONTAR.SI(A1:A10;"<>"&MAX(A1:A10))-CONTAR.SI(A1:A10;MIN(A1:A10)))

las siguientes formulas son matriciales y por tanto se deben confirmar
mediante la combinacion de teclas CTRL+SHIFT+ENTER

=PROMEDIO(SI(A1:A10<>MAX(A1:A10);SI(A1:A10<>MIN(A1:A10);A1:A10)))

=PROMEDIO(SI((A1:A10<>MAX(A1:A10))*(A1:A10<>MIN(A1:A10));A1:A10))

tambien se podria hacerlo de la siguiente forma, pero es casi dos veces mas
lenta (en XL2007) que cualquiera de las anteriores:

=SUMAPRODUCTO(--(A1:A10<>MAX(A1:A10));--(A1:A10<>MIN(A1:A10));A1:A10)/SUMAPRODUCTO(--(A1:A10<>MAX(A1:A10));--(A1:A10<>MIN(A1:A10));--(A1:A10<>""))

Saludos,
KL