crear una tabla.bdf de una base de datos sql

Mediante SSIS (Integration Services). Busca en los libros de en pantalla de
SQL y verás la información.
Para verlo rápidamente puedes hacer la exportación de una tabla con el botón
de derecho del ratón y verás que al final hay una opción que es guardar la
transformación en un paquete de IS. Esa transformación la puedes ejecutar
cada periodo de tiempo o llamarla desde tu programa mediante SMO.

Un saludo
Oscar Montesinos
"pavel" escribió en el mensaje
news:

hola tengo un programa ke corre en windows y kisiera saber como hacer para
ke
la base de datos ke tengo en sql2005 lo exporte o cree a una tabla.bdf o
visual fox 6 ya ke el programa donde debe de ir es uno creado en visual
fox y
se debe de llenar la base de datos ahi
espero ke me ayan entendido y ke me ayuden
gracias de antemano

"pavel" preguntó:

kisiera saber como hacer para ke la base de datos ke
tengo en sql2005 lo exporte o cree a una tabla.bdf o
visual fox 6 ...

Bueno, en éste mensaje se entiende mejor lo que pretendes hacer, que el que
enviástes en el día de ayer. :-)

Puedes crear fácilmente el archivo de dBASE o de FoxPro, utilizando el
proveedor de datos Ole Db .NET, junto con el ISAM instalable XBase del motor
Microsoft Jet, para conectarte vía ODBC con la base de datos de SQL Server
2005, de tal forma que ejecutando una simple consulta SQL de creación de
tabla, podrás crear un nuevo archivo *.dbf. Aquí tienes un ejemplo:

' Construimos la cadena de conexión Ole Db,
' indicando que vamos a utilizar el ISAM para XBase,
' y la carpeta donde se creará C:\Mis documentos
'
Dim connString As String = _
"Provider = Microsoft.Jet.OLEDB.4.0;" & _
"Data Source = C:\Mis documentos;" & _
"Extended Properties = 'dBASE 5.0;'"

' Creamos un nuevo objeto Connection
'
Dim cnn As New OleDbConnection(connString)

Try
' Creamos la consulta SQL de creación de tabla,
' indicando que vamos a utilizar el driver
' ODBC de Microsoft SQL Native Client
'
Dim sql As String = _
"SELECT * INTO Archivo#dbf " & _
"FROM [Nombre_Tabla_Base_SQLServer2005] " & _
"IN ''[ODBC;DRIVER={SQL Native Client};" & _
"Server=Nombre_Instancia_Servidor_SQL;" & _
"Database=Nombre_Base_Datos_SQL2005;" & _
"UID=Cuenta_Usuario;" & _
"PWD=Contraseña_Usuario]"

' Configuramos un objeto Command para ejecutar
' la consulta SQL de creación de tabla
'
Dim cmd As New OleDbCommand(sql, cnn)

' Abrimos la conexión
cnn.Open()

' Ejecutamos la consulta
Dim n As Integer = cmd.ExecuteNonQuery()

MessageBox.Show("Se creado satisfactoriamente el archivo." & _
ControlChars.CrLf & _
"Número de registros afectados: " & n.ToString, _
"Crear archivo dBASE")

Catch ex As OleDbException
MessageBox.Show(ex.Errors(0).Message)

Catch ex As Exception
MessageBox.Show(ex.Message)

Finally
' Cerramos la conexión
cnn.Close()
cnn = Nothing

End Try

Enrique Martínez
[MS MVP - VB]

Nota informativa: La información contenida en este mensaje, así como el
código fuente incluido en el mismo, se proporciona «COMO ESTÁ», sin
garantías de ninguna clase, y no otorga derecho alguno. Usted asume
cualquier riesgo al poner en práctica, utilizar o ejecutar lo recomendado o
sugerido en el presente mensaje.