Celdas con valores

Hola Grupo,

Nuevamente molestando con una duda.
Que formula puedo utilizar para tomar unicamente las ultimas cuatro celdas
que contienen valores de un rango de 12.

Es decir, tengo valores en las columnas A a la L (una por mes), y en la M
tengo una columa promedio, as:

A B C D E F G H I
J K L M
1 Ene Feb Mar Abr May Jun Jul Ago Sep Oct
Nov Dic Promedio
2 15 5 10 10
20 30 15 18.75
3 10 15 20
25 17
4 8 12 15 13 16 14
14 12 14

Lo que necesito es que en la columna Promedio, me saque el promedio de los
ultimos cuatro valores (meses) del ao.
El punto es que hay registros (filas) que no traen valores en algunos meses
y en otros si. Yo necesito promediar los que si traen (ultimos cuatro).
Puede ser tambien que el registro (Fila), unicamente tenga dos valores en el
ao, Asi que necesito promedio de esos dos. Y si tiene valores en todos los
meses del ao, necesito el promedio unicamente de los ultimos cuatro.


Gracias y saludos,

Hola, Fajardo.

Creando una estructura estrictamente como la que nos posteas, te podría
plantear una solución rápida utilizando cálculos en columnas auxiliares,
las
que después puedes ocultar o proteger de alguna forma. Sólo ten presente
que
mi separador de parámetros es la coma, si no te funcionan las fórmulas,
cámbialas por punto y coma.

Intenta con las siguientes fórmulas, y comentas a ver si te son útiles:

1. Celda AA2
Introduce la siguiente fórmula:
=SI(ESBLANCO(A2),0,1)+AB2
y cópiala hasta AL2. Luego la copias hacia abajo, hasta donde sea
necesario
según las filas de datos que tengas.

2. Celda M2
Introduce la siguiente fórmula:
=SUMAPRODUCTO(A2:L2,(AA2:AL2>0)*1,(AA2:AL2<=4)*1)/SI(CONTARA(A2:L2)>4,4,CONTARA(A2:L2))
y cópiala hacia abajo hasta donde terminen las filas de tus datos.

Esperamos tus comentarios para ver si hay necesidad de algún ajuste en las
fórmulas.

Saludos...



"Fajardo" escribió:

Hola Grupo,

Nuevamente molestando con una duda.
Que formula puedo utilizar para tomar unicamente las ultimas cuatro
celdas
que contienen valores de un rango de 12.

Es decir, tengo valores en las columnas A a la L (una por mes), y en la M
tengo una columa promedio, as:

A B C D E F G H
I
J K L M
1 Ene Feb Mar Abr May Jun Jul Ago Sep Oct
Nov Dic Promedio
2 15 5 10 10
20 30 15 18.75
3 10 15 20
25 17
4 8 12 15 13 16
14
14 12 14

Lo que necesito es que en la columna Promedio, me saque el promedio de
los
ultimos cuatro valores (meses) del ao.
El punto es que hay registros (filas) que no traen valores en algunos
meses
y en otros si. Yo necesito promediar los que si traen (ultimos cuatro).
Puede ser tambien que el registro (Fila), unicamente tenga dos valores en
el
ao, Asi que necesito promedio de esos dos. Y si tiene valores en todos
los
meses del ao, necesito el promedio unicamente de los ultimos cuatro.


Gracias y saludos,

hola, chicos ! (solo por no dejarlo en el tintero)...

prueba tambien seleccionando la celda M2 y creando/definiendo/... los
siguientes nombres:
nombre: formula:
Cols =si($a2:$l2<>"",columna($a2:$l2)-columna($a$2))
nCols =min(4,contar($a2:$l2))
xCols =fila(indirecto("1:"&ncols))
xMatriz =k.esimo.mayor(cols,xcols)
miPromedio =sumaproducto(subtotales(9,desref($a2,,xmatriz)))/ncols

al final solo aplicas a cada celda en la columna M "el nombre":
=mipromedio

pros: no utiliza calculos "forward" (dependientes de calculos en columnas
posteriores)
tampoco requiere de las columnas auxiliares (posteriores)

cons: un exceso de celdas modificando nombres podria alentar los
(re)calculos del modelo
(probablemente seria casi igual que calcular a posteriori las 12
columnas auxiliares en cada fila ?)

puedes no definir el ultimo nombre (miPromedio) y aplicar la formula
(iniciando en la celda M2)
=sumaproducto(subtotales(9,desref($a2,,xmatriz)))/ncols

tambien podrias recortar (un poco) la formula propuesta por David (+/- a
lo siguiente:)
=sumaproducto(a2:l2,(aa2:al2>0)*(aa2:al2<=4))/min(contara(a2:l2),4)

saludos,
hector.

Hola tocayo,

Como siempre... excelente aporte.
Gracias por tu ayuda.

Saludos,


"Héctor Miguel" escribió en el mensaje de
noticias news:

hola, chicos ! (solo por no dejarlo en el tintero)...

prueba tambien seleccionando la celda M2 y creando/definiendo/... los
siguientes nombres:
nombre: formula:
Cols =si($a2:$l2<>"",columna($a2:$l2)-columna($a$2))
nCols =min(4,contar($a2:$l2))
xCols =fila(indirecto("1:"&ncols))
xMatriz =k.esimo.mayor(cols,xcols)
miPromedio =sumaproducto(subtotales(9,desref($a2,,xmatriz)))/ncols

al final solo aplicas a cada celda en la columna M "el nombre":
=mipromedio

pros: no utiliza calculos "forward" (dependientes de calculos en columnas
posteriores)
tampoco requiere de las columnas auxiliares (posteriores)

cons: un exceso de celdas modificando nombres podria alentar los
(re)calculos del modelo
(probablemente seria casi igual que calcular a posteriori las 12
columnas auxiliares en cada fila ?)

puedes no definir el ultimo nombre (miPromedio) y aplicar la formula
(iniciando en la celda M2)
=sumaproducto(subtotales(9,desref($a2,,xmatriz)))/ncols

tambien podrias recortar (un poco) la formula propuesta por David (+/- a
lo siguiente:)
=sumaproducto(a2:l2,(aa2:al2>0)*(aa2:al2<=4))/min(contara(a2:l2),4)

saludos,
hector.