Ayuda para una comparación entre tres valores

Suponiendo que los 3 porcentajes están en A1, B1 y C1 (y en espera de una
fórmula más sencilla):
=ELEGIR(SI(CONTAR.SI(A1:C1;MAX(A1:C1))=3;7;1*(A1=MAX(A1:C1))+2*(B1=MAX(A1:C1))+4*(C1=MAX(A1:C1)));"A";"B";"AB";"C";"AC";"BC";"ABC")

Saludos desde Tenerife.
***********************
"gorigori" escribió en el mensaje
news:
Hola, quisiera hacer lo siguiente pero no me sale bien:
Supongamos que tengo tres valores, cada uno de los cuales es un
porcentaje:

A B C
50 20 30

Los tres porcentajes sumados suman 100. Al primer porcentaje lo
llamamos A, al segundo B y al tercero C.

Quisiera una formula para que me elija el porcentaje mayor de los
tres, en este caso como es 50, y me escriba en otra celda: A, que es
(digamos) el nombre dle primer valor.

En este caso:
A B C
10 30 60

Debería escribir C.


Pero, si el porcentaje más alto se repite, ejemplo:

20 40 40

que me escribiera los dos porcentajes más altos, en este caso sería BC

y si fueran los tres iguales, por ejemplo

33 33 33

que me escribiera ABC.


¿Sabéis como podría hacer eso?

Gracias

hola, chicos !

gorigori escribio en el mensaje ...
Supongamos que tengo tres valores, cada uno de los cuales es un porcentaje:
A B C
50 20 30
Los tres porcentajes sumados suman 100. Al primer porcentaje lo llamamos A, al segundo B y al tercero C.
Quisiera una formula para que me elija el porcentaje mayor de los tres, en este caso como es 50, y me escriba en otra celda: A
En este caso: 10 30 60
Deberia escribir C.
Pero, si el porcentaje mas alto se repite, ejemplo: 20 40 40
que me escribiera los dos porcentajes más altos, en este caso seria BC
y si fueran los tres iguales, por ejemplo: 33 33 33
que me escribiera ABC.

AnSanVal escribio en el mensaje ...
Suponiendo que los 3 porcentajes estan en A1, B1 y C1 (y en espera de una formula mas sencilla):
=ELEGIR(SI(CONTAR.SI(A1:C1;MAX(A1:C1))=3;7;1*(A1=MAX(A1:C1))+2*(B1=MAX(A1:C1))+4*(C1=MAXA1:C1)));"A";"B";"AB";"C";"AC";"BC";"ABC")

-> suponiendo los datos en 'A2:C2' [por si decides poner los nombres en el rango 'A1:C1'] :))

op1: para 'adelgazar' la formula se podrian omitir las funciones SI y CONTAR.SI +/- como sigue:
=elegir((a2=max(a2:c2))+2*(b2=max(a2:c2))+4*(c2=max(a2:c2)),"a","b","ab","c","ac","bc","abc")

op2: usando matrices 'constantes' +/- como sigue:
=elegir(sumaproducto({1;2;4}*(a2:c2=max(a2:c2))),"a","b","ab","c","ac","bc","abc")

OJO: mi sistema usa como separador de argumentos a la coma
y usa el punto y coma para separar COLUMNAS en matrices constantes -> {1;2;4}

si quieres sustituir los valores 'constantes' "A", "B" y "C" por algun otro 'texto' en el rango 'A1:C1'
cambiar las referencias a los valores 'elegidos'...
de: -> "a","b","ab","c","ac","bc","abc"
a: -> a1,b1,a1&"-"&b1,c1,a1&"-"&c1,b1&"-"&c1,a1&"-"&b1&"-"&c1

saludos,
hector.

Gracias Héctor :-))

La corrección propuesta en tu opción 1, me parece bien.
Pero la que realmente me ha gustado es la opción 2. Esta va para mi
"histórico". ;-)

Saludos desde Tenerife (España).
*******************************
"Héctor Miguel" escribió en el mensaje
news:

hola, chicos !

gorigori escribio en el mensaje ...
Supongamos que tengo tres valores, cada uno de los cuales es un
porcentaje:
A B C
50 20 30
Los tres porcentajes sumados suman 100. Al primer porcentaje lo llamamos
A, al segundo B y al tercero C.
Quisiera una formula para que me elija el porcentaje mayor de los tres,
en este caso como es 50, y me escriba en otra celda: A
En este caso: 10 30 60
Deberia escribir C.
Pero, si el porcentaje mas alto se repite, ejemplo: 20 40 40
que me escribiera los dos porcentajes más altos, en este caso seria BC
y si fueran los tres iguales, por ejemplo: 33 33 33
que me escribiera ABC.

AnSanVal escribio en el mensaje ...
Suponiendo que los 3 porcentajes estan en A1, B1 y C1 (y en espera de
una formula mas sencilla):
=ELEGIR(SI(CONTAR.SI(A1:C1;MAX(A1:C1))=3;7;1*(A1=MAX(A1:C1))+2*(B1=MAX(A1:C1))+4*(C1=MAXA1:C1)));"A";"B";"AB";"C";"AC";"BC";"ABC")

-> suponiendo los datos en 'A2:C2' [por si decides poner los nombres en el
rango 'A1:C1'] :))

op1: para 'adelgazar' la formula se podrian omitir las funciones SI y
CONTAR.SI +/- como sigue:

=elegir((a2=max(a2:c2))+2*(b2=max(a2:c2))+4*(c2=max(a2:c2)),"a","b","ab","c","ac","bc","abc")

op2: usando matrices 'constantes' +/- como sigue:

=elegir(sumaproducto({1;2;4}*(a2:c2=max(a2:c2))),"a","b","ab","c","ac","bc","abc")

OJO: mi sistema usa como separador de argumentos a la coma
y usa el punto y coma para separar COLUMNAS en matrices
constantes -> {1;2;4}

si quieres sustituir los valores 'constantes' "A", "B" y "C" por algun
otro 'texto' en el rango 'A1:C1'
cambiar las referencias a los valores 'elegidos'...
de: -> "a","b","ab","c","ac","bc","abc"
a: -> a1,b1,a1&"-"&b1,c1,a1&"-"&c1,b1&"-"&c1,a1&"-"&b1&"-"&c1

saludos,
hector.