Ayuda para encontrar valor max y minimo

hola, Antonio !

1) las formulas que expones, donde se hace referencia a celdas de la columna 'C'... de donde salen, que significan... ?

2) si necesitas encontrar los valores 'anterior y posterior' del dato que buscas...
-> suponiendo que los datos de la tabla estan en el rango 'A1:B8'... <= OJO
prueba con las siguientes aproximaciones:
[C1] -> 2.35 [o el dato 'buscado']
[D1] -> 4873.215 formula: =(d2-d3)/2+d2 [algo asi como una aproximacion de 'ponderado'] ;)
[C2] -> 2.34 formula: =buscarv(c1,a1:a8,1)
[D2] -> 4895.81 formula: =buscarv(c1,a1:b8,2)
[C3] -> 2.36 formula: =indice(a1:a8,coincidir(c1,a1:a8)+1)
[D3] -> 4941.00 formula: =indice(b1:b8,coincidir(c1,a1:a8)+1)

3) o... puedes utilizar la funcion 'pronostico' [combinada con desref y coincidir] para obtener un 'pronostico' +/- 'aceptable' [p.e.]
[C1] -> 2.35 [o el dato buscado]
[D1] -> 4918.405 formula: =pronostico(c1,desref(a1:a8,coincidir(c1,a1:a8)-1,1,2,1),desref(a1:a8,coincidir(c1,a1:a8)-1,0,2,1))

-> 'nota' la diferencia entre un 'acercamiento' [punto 2-> 4873.215] 'versus' un pronostico [punto 3-> 4918.405]
-> toma nota que mi sistema usa como separador de argumentos a la coma ',' NO al punto y coma ';' :D

si cualquier duda [o informacion adicional]... comentas ?
saludos,
hector.

__ la consulta original __

... tengo que estar sacando valores de una tabla y para ello tengo que hacer interpolaciones
... formula que al poner un valor buscado... encuentre el valor minimo y maximo
asi como el valorcorrespondiente a la celda de a lado de estos valores, pongo un ejem [...]
A B
2.280 4760.39
2.300 4805.51
2.320 4850.65
2.340 4895.81
2.360 4941.00
2.380 4986.22
2.400 5031.46
2.420 5076.73

Los datos que necesito me aparescan serian estos
A B
valor menor 2.340 4895.81
valor buscado 2.350 =((C4-C2)/(B4-B2))*(B3-B2)+C2
valor menor 2.360 4941.00

hola [de nuevo], Antonio !

es posible que te sean de utilidad otras 'variantes' [de entre mas posibilidades] p.e.

si seguimos suponiendo que los datos de 'la tabla' estan en el rango 'A1:B8'
y que en 'C1' pones el dato 'a buscar'...
y que la 'tendencia' en la tabla sera siempre 'uniforme' [como en el ejemplo con 'saltos' de 0.02]

1) cuando el dato a buscar coincide exactamente con algun valor 'minimo' de la tabla...
=buscarv(c1,a1:b8,2)

2) cuando el dato a buscar NO coincide con algun valor de la tabla...
primero habria que 'descartar' algun error de busqueda 'exacta' para saber que se trata de un valor 'intermedio' :))
=si(eserror(buscarv(c1,a1:a8,1,0)),(buscarv(c1,a1:b8,2)+indice(b1:b8,coincidir(c1,a1:a8)+1))/2,buscarv(c1,a1:b8,2))

3) si el dato a buscar sear siempre 'intermedio' -?-
=(buscarv(c1,a1:b8,2)+indice(b1:b8,coincidir(c1,a1:a8)+1))/2

4) para cualquier otro caso, suponiendo saltos no constantes o valores 'medio-intermedios' [p.e. 2.315 o 'similar']...
'volver' al uso de la funcion 'pronostico'...
=pronostico(c1,desref(a1,coincidir(c1,a1:a8)-1,1,2,1),desref(a1,coincidir(c1,a1:a8)-1,,2,1))

[mientras encontramos otras variantes, o expones algun detalle mas... 'concreto' :))

saludos,
hector.

Héctor Miguel ha escrito:

hola [de nuevo], Antonio !

es posible que te sean de utilidad otras 'variantes' [de entre mas posibilidades] p.e.

si seguimos suponiendo que los datos de 'la tabla' estan en el rango 'A1:B8'
y que en 'C1' pones el dato 'a buscar'...
y que la 'tendencia' en la tabla sera siempre 'uniforme' [como en el ejemplo con 'saltos' de 0.02]

1) cuando el dato a buscar coincide exactamente con algun valor 'minimo' de la tabla...
=buscarv(c1,a1:b8,2)

2) cuando el dato a buscar NO coincide con algun valor de la tabla...
primero habria que 'descartar' algun error de busqueda 'exacta' para saber que se trata de un valor 'intermedio' :))
=si(eserror(buscarv(c1,a1:a8,1,0)),(buscarv(c1,a1:b8,2)+indice(b1:b8,coincidir(c1,a1:a8)+1))/2,buscarv(c1,a1:b8,2))

3) si el dato a buscar sear siempre 'intermedio' -?-
=(buscarv(c1,a1:b8,2)+indice(b1:b8,coincidir(c1,a1:a8)+1))/2

4) para cualquier otro caso, suponiendo saltos no constantes o valores 'medio-intermedios' [p.e. 2.315 o 'similar']...
'volver' al uso de la funcion 'pronostico'...
=pronostico(c1,desref(a1,coincidir(c1,a1:a8)-1,1,2,1),desref(a1,coincidir(c1,a1:a8)-1,,2,1))

[mientras encontramos otras variantes, o expones algun detalle mas... 'concreto' :))

saludos,
hector.

Hector, antes que nada gracias por tu ayuda, estoy checando lo que me
comentas, pero creo que no me supe explicar bien veras, te envie un
ejemplo de una tabla donde tengo 2 columnas A Y B, en la columna A
tengo unos valores que son de longitud (cm) y en la B su valor
correspondiente en volumen (m3). (Es una tabla de 600 valores en la
columna A con diferencia de 0.020), si el valor que yo busco en la
columna A esta entre 2 valores como en el ejem. tengo que tomar el
valor menor y el mayor con sus correspondientes volumenes e interpolar
para sacar el volumen que le corresponderia al valor buscado.
A B
valor menor
valor buscado 2.350 =((C4-C2)/(B4-B2))*(B3-B2)+C2 con esta
formula saco el volumen corresp al valor de 2.350
valor mayor
En este ejemplo el valor que busco es 2.350, este valor cae entre el
valor de la columna A, de 2.340 y 2.360, entonces anoto el valor de la
columna A 2.340 (valor menor) y su valor correspondiente de la colum B
(4895.81) y anoto el valor de 2.360 (valor mayor ) y su valor
correspondiente de la columna B (4941.00) y con esos valores realizo la
interpolación (mediante la formula que tengo) y saco el valor del
volumen del valor buscado en este caso 2.350 le corresponderia un
volumen de 4918.41
A B
2.280 4760.39
2.300 4805.51
2.320 4850.65
2.340 4895.81
2.360 4941.00
2.380 4986.22
2.400 5031.46
2.420 5076.73
Diariamente necesito sacar 35 valores (volumenes) de la tabla. La
pregunta es si hay alguna formula que me ponga el valor menor y mayor
con sus respectivos valores de la columna B, cuando el valor que busque
en la columna A sea un valor intermedio de los valores existentes.
Espero me halla explicado mejor
Saludos..

hola, Antonio !

antes de continuar con este 'desarrollo' de propuestas de solucion... una pregunta:

-> ya intentaste con -al menos- una de las propuestas ?

lo unico que no conozco es el rango donde esta la tabla [por ello te comunico 'mis' supuestos] ;)

si cualquier duda [o informacion adicional]... comentas ?
saludos,
hector.

Héctor Miguel ha escrito:

hola, Antonio !

antes de continuar con este 'desarrollo' de propuestas de solucion... una pregunta:

-> ya intentaste con -al menos- una de las propuestas ?

lo unico que no conozco es el rango donde esta la tabla [por ello te comunico 'mis' supuestos] ;)

si cualquier duda [o informacion adicional]... comentas ?
saludos,
hector.

Hector, creo que me adelante a responderte en eso he estado y una de
las variantes que me enviaste (4) la de valores "medio-intemedios"
aplica perfectamente estoy haciendo ejemplos y funciona muy bien, antes
de eso cheque por separado las variantes 1 y 3 y me funcionaba para
valores exactos e intermedios ejemp 2.25 pero al poner en valor de 3
decimales (2.251) no me daba el valor correcto y con la 4 variante me
funciona en los 2 casos. Una pregunta mas si quiero que de la misma
columna A me ponga datos de una colomna C, D etc unicamente le cambio
el numero del dato de la columna que quiero poner??
Muchas garcias Hector por tu ayuda!!