anidar funciones condicionales

Dependiendo de cómo sea tu problema, puede tener varias soluciones.
Quizá con la función BUSCARV, o con ÍNDICE y/o COINCIDIR se resuelva.

Si das algunos detalles más, es posible que podamos darte la fórmula
concreta que necesites.

:-)

Hola compañeros:

No soy un gran entendido en excell pero intento salir adelante lo
mejor que puedo con este programa.
Mi problema es que necesitaría anidar unos 11 datos condicionales pero
excell solo permite 6. ¿Hay alguna solución a mi alcance?
Soy bastante novatillo, como ya dije antes.

Gracias mil, por vuestro interés

hola, (...) ?

... necesitaria anidar unos 11 datos condicionales pero excell solo permite 6
Hay alguna solucion a mi alcance? Soy bastante novatillo, como ya dije antes.

1) cuando se vuelve 'necesario' ANIDAR demasiadas[?] funciones SI condicionales...
[yo creo que] es tiempo de pensar en alguna forma diferente de 'validar' resultados condicionados [p.e.]

- si las condiciones a 'evaluar' son valores consecutivos [1,2,3,4,5,6,etc.] ->a partir de 1, Y NO CERO<- ...
resulta mas 'conveniente' la funcion =elegir(resultado_de_la_condicion,alternativa_1,alternativa_2[,alternativa_x])

- si las condiciones a 'evaluar' son resultados de 'expresiones_valor' ...
podrias sumar [solamente] 'aquellos' valores cuyas condiciones 'se cumplen' [p.e.]
=(condicion=valor1)*resultado1+(condicion=valor2)*resultado2+(condicion=valor3)*resultado3[+(condicion..]

- podrias 'romper' en condiciones parciales [usando celdas distintas y/o nombres] y 'dejar' la que se cumpla
[p.e.] =si(condicion_parcial_1,solucion_parcial_1,buscar_otra_condicion)

2) de todas formas seria conveniente que expongas detalles mas... concretos' ;)

saludos,
hector.

Antes de nada gracias a Victor y a Héctor Miguel:

Soy maestro y estoy confeccionando una hoja de cálculo que me permita
llevar el seguimiento de mis alumnos.
La cosa se me ha complicado porque quiero que en una casilla EXCELL me
devuelva una nota numérica a partir de dos notas alfanuméricas. Esto
debo repetirlo en la misma hoja de seguimiento de cada alumno unas 20
veces, ya que preveo que al final del trimestre tendré entre 12 y
veinte notas de cada alumno

Si pudiera anidar anidar las funciones que necesito, la formula
quedaría así, para que me devolviera la nota que preciso:
=SI(Y(J8="E";J9="E");10;SI(Y(J8="E";J9="AN");9;SI(Y(J8="AN";J9="E");
9;SI(Y(J8="E";J9="A");8;SI(Y(J8="A";J9="E");8;SI(Y(J8="AN";J9="AN");
7;SI(Y(J8="AN";J9="A");6;SI(Y(J8="A";J9="AN");6;SI(Y(J8="E";J9="I");
6;SI(Y(J8="I";J9="E");6;SI(Y(J8="A";J9="A");5;SI(Y(J8="AN";J9="I");
5;SI(Y(J8="I";J9="AN");5;SI(Y(J8="I";J9="A");4;SI(Y(J8="A";J9="I");
4;SI(Y(J8="I";J9="I");2;SI(Y(J8="";J9="");"")... con los parentesis
que correspondan.

Espero que con esta "aclaración" os sea más facil ayudarme.
Mis mas sinceras gracias
Félix

hola, Félix !

[primero] unas notas *acostumbradas* para aclarar asuntos regionales en cuanto a los separadores...

toma en cuenta que mi sistema usa como separador de argumentos a la coma ',' NO al punto y coma ';' :D
tambien utiliza la barra invertida para separar *filas* en matrices constantes o entre llaves como: -> {x\y\z}

es probable/seguro/... que necesites modificar *mi* coma por punto y coma
lo que no te puedo *averiguar* es que caracter necesite tu configuracion regional para la barra invertida -?-

comentado lo anterior, prueba con la siguiente formula:

=redondear(sumaproducto(contar.si(j8:j9,{"e"\"an"\"a"\"i"}),{10\7\5\2})/2,0)

si cualquier duda [o informacion adicional]... comentas ?
saludos,
hector.

__ la consulta original __

... estoy confeccionando una hoja de calculo que me permita llevar el seguimiento de mis alumnos.
... se me ha complicado porque quiero que... devuelva una nota numerica a partir de dos notas alfanumericas
... debo repetirlo en la misma hoja de seguimiento de cada alumno unas 20 veces
... preveo que al final del trimestre tendre entre 12 y veinte notas de cada alumno
Si pudiera anidar anidar las funciones que necesito, la formula quedaria asi, para que me devolviera la nota que preciso:

=SI(Y(J8="E";J9="E");10;SI(Y(J8="E";J9="AN");9;SI(Y(J8="AN";J9="E");9;SI(Y(J8="E";J9="A");8;
SI(Y(J8="A";J9="E");8;SI(Y(J8="AN";J9="AN");7;SI(Y(J8="AN";J9="A");6;SI(Y(J8="A";J9="AN");6;
SI(Y(J8="E";J9="I");6;SI(Y(J8="I";J9="E");6;SI(Y(J8="A";J9="A");5;SI(Y(J8="AN";J9="I");5;
SI(Y(J8="I";J9="AN");5;SI(Y(J8="I";J9="A");4;SI(Y(J8="A";J9="I");4;SI(Y(J8="I";J9="I");2;SI(Y(J8="";J9="");"")

... con los parentesis que correspondan.
Espero que con esta "aclaracion" os sea mas facil ayudarme.
Mis mas sinceras gracias
Félix

GRACIAS HECTOR POR LAS MOLESTIAS.
Voy haciendo diferentes modificaciones a la hoja y todo va, creo,
bastante bien.

Félix