URGENTE:Extender en excel

Hola J.Manuel,

Suponiendo que...
1) los nombres de las hojas son "1","2","3",..."52" segun la semana
2) los datos se encuentran en rangos identicos en todas las hojas

Prueba lo siguiente:

1) en el rango [A1:A52] de la hoja de resumen pon los valores 1,2,3,...52
2) en la celda [B1] pon la siguiente formula y copiala hacia abajo:

=INDIRECTO("'"&A1&"'!A1")

Si no quieres crear la lista 1,2,3,...52 en una columna aparte, podrias
introducir el contador dentro de la formula:

=INDIRECTO("'"&FILA(A1)-FILA($A$1)+1&"'!A1")

Si ademas de los numeros los nombres de hojas contienen algun texto
adicional (pero uniforme, p.ej: "Semana1", "Semana2", etc.), podrias hacer:

=INDIRECTO("'Semana"&A1&"'!A1")

Tambien puedes operar con rangos de varias celdas a la vez, p.ej.:

=SUMA(INDIRECTO("'Semana"&A1&"'!A1:A20"))
=VLOOKUP(C1;INDIRECTO("'Semana"&A1&"'!A1:D20");2;FALSO)

Y tambien puedes hacer las referencias relativas:

=INDIRECTO("'Semana"&A1&"'!"&DIRECCION(FILA(A1);COLUMNA(A1)))

Saludos,
KL


"J.Manuel" wrote in message
news:%
Mostrar la cita

Buenos Días.

Tengo un libro de excel compuesto de varias hojas.Tengo muchas hojas
dentro del libro,cada una asignada a una semana del año(52 semanas = 52
hojas distintas).Dentro del mismo libro,a modo de resumen tengo otra hoja
llamada Resumen Semanal donde aparecerían los datos más destacados de cada
semana.Eso lo tengo hecho para la primera semana,es decir,para una
hoja(con enlaces de formulas y funciones).

Mi duda es la siguiente:¿En la hoja de Resumen Semanal,puedo extender de
alguna manera la fila correspondiente a la primera semana,y que las
siguientes filas(que corresponderían a las siguientes semanas)tuvieran
enlaces no a la primera hoja,sino a las demás sucesivamente?

Se que es complicado,pero básicamente lo que quiero saber es si hay alguna
forma de extender una fila hacia abajo y que vallan cambiando los enlaces
referentes a distintas hojas,y que no se mantenga el enlace a la primera.