Si es Mayor que zero

Hola Sam,

Prueba el codigo de abajo. Cambia los nombres de hojas si es necesario. Este
macro copiara todas las filas de la hoja1 cuyas celdas en la columna [C] no
sean iguales a 0. Es decir, si disparas el macro mas de una vez sin haber
cambiado los datos en la hoja1, se crearan duplicados en la hoja2.

Saludos,
KL

'Inicio Codigo--
Sub test()
Dim rngOrig As Range
Dim rngDest As Range
Dim celda As Range

'Congela la pantalla
Application.ScreenUpdating = False

'Define el rango de busqueda
With Worksheets("Hoja1")
Set rngOrig = Intersect(.Columns(3), .UsedRange)
End With

'Redimensiona el rango de busqueda para
'excluir los titulos de columnas.
With rngOrig
Set rngOrig = .Resize(.Rows.Count - 1, 1).Offset(1, 0)
End With

'Busca celdas en el rango de busqueda
'que no sea igual a 0.
For Each celda In rngOrig
If celda <> 0 Then

'Busca y define la primera fila
'vacia en la hoja de destino.
With Worksheets("Hoja2")
Set rngDest = .Cells(.Rows.Count, 3) _
.End(xlUp).Offset(1, 0).EntireRow
End With

'Copia la fila entera de la celda
'encontrada a la fila de destino.
celda.EntireRow.Copy rngDest
End If
Next celda

'Descongela la pantalla
Application.ScreenUpdating = True
End Sub
'Fin Codigo--


"Sam Venezuela" wrote in message
news:

si estoy buscando una informacion de numero en una celda,
buscar en la columna (C) en hoja1 que no es zero copiar la fila completa a
la hoja2 al sigiente espacio desponible en la hoja2 .

Grascias

Sam Venezuela