Ordenar Izquierda Derecha Izquierda

Compumakro escribió:

Amigos de Word2003
..tengo una tabla con 2 columnas.(Nombre, Dirección, Teléfono)
Constantemente cambia, salen y entran datos.
.. se necesita ordenar alfabéticamente
de izquierda (1ª columna )a derecha (2ª columna)


Columna1 Columna2
Abita Acor
Amute Babu
Bebe Cota

Gracias
Oscar

HOla Oscar :-)

Prueba con este codigo que he modificado del author original [ Gregmaxey
MVP word ] :

Inserta el codigo en un Modulo :

'-
Sub Ord_Tablas_Izq_Dcha()

Dim i As Long
Dim Tabla As Table
Dim Documento As Word.Document
Dim proyectar As Table


If Not Selection.Information(wdWithInTable) Then
MsgBox "Situese en una celda please..."
Exit Sub
End If


Set Tabla = Selection.Tables(1)
i = Tabla.Range.Cells.Count


Set Documento = Documents.Add(Visible:=True)
Set proyectar = Documento.Tables.Add(Documento.Content, i, 1)

CopiarTabla Tabla, proyectar

proyectar.Sort

CopiarTabla proyectar, Tabla

Documento.Close SaveChanges:=False

Exit Sub

End Sub

Sub CopiarTabla(izq As Table, dcha As Table)

Dim posicion1 As Word.Cell
Dim posicion2 As Word.Cell
Set posicion1 = izq.Cell(1, 1)
Set posicion2 = dcha.Cell(1, 1)

Do
posicion2.Range = Left(posicion1.Range, Len(posicion1.Range) - 2)
Set posicion1 = posicion1.Next
Set posicion2 = posicion2.Next
Loop Until posicion1 Is Nothing

End Sub

'

Prueba y nos comentas :-)

Saludos
Monica



Estado: A la Espera By Fermu

Tic-Tac-Tic-Tac...

Now We are free [Enya]

www.fermu.com