Inicializar botones de opción desactivados

"luka79" escribió en el mensaje news:

Tengo varios cuadros de grupo en una hoja y me interesa que aparezcan todas
las opciones como desactivadas
¿se puede hacer?
Gracias anticipadas a todos
Javier.B.A

Prueba con alguno de estos dos Subs o con ambos, dependiendo de cómo hayas creado los controles: con la barra de herramientas "Formulario", con la barra de herramientas "Cuadro de controles" o mezclados.

Sub DesactivarControles1()
'Si están creados mediante la barra de herramientas "Formulario"
Dim cb As CheckBox
Dim ob As OptionButton

For Each cb In Worksheets("Hoja1").CheckBoxes
cb.Value = False
Next cb

For Each ob In Worksheets("Hoja1").OptionButtons
ob.Value = False
Next ob

Set ob = Nothing
Set cb = Nothing
End Sub


Sub DesactivarControles2()
'Si están creados mediante la barra de herramientas "Cuadro de controles"
Dim n As Integer

With Worksheets("Hoja1")
For n = 1 To .OLEObjects.Count
If TypeName(.OLEObjects(n).Object) = "CheckBox" Then
.OLEObjects(n).Object.Value = False
End If
Next n

For n = 1 To .OLEObjects.Count
If TypeName(.OLEObjects(n).Object) = "OptionButton" Then
.OLEObjects(n).Object.Value = False
End If
Next n
End With
End Sub


Tendrás que cambiar Hoja1 por el nombre real de la hoja.
Un saludo.


Fernando Arroyo
MS MVP - Excel
www.excelesp.com