Excel y C#

"Francisco Matamoros" escribió:

Tendría que saber cómo se llaman las hojas que componen el xls, y en un
combo que me eligiera cuál quiere rellenar, ...

Hola, Francisco:

El método «GetSchema» de un objeto OleDbConnection, te devuelve un objeto
DataTable con la información de esquema del origen de datos especificado.

Traduce a C# el código de la siguiente función escrita en Visual Basic .net:

Private Function GetRangesAndSheetsNames( _
ByVal connString As String, _
ByVal includeSheets As Boolean, _
ByVal includeRanges As Boolean) As String()

If (connString = String.Empty) Then Return Nothing

Dim cnn As OleDbConnection = Nothing

Try
cnn = New OleDbConnection(connString)
cnn.Open()

Dim dt As DataTable = cnn.GetSchema("TABLES")

Dim tables() As String = Nothing
Dim o As Object = Nothing
Dim n As Int32 = 0

If dt.Rows.Count > 0 Then

For Each dr As DataRow In dt.Rows

o = dr.Item("TABLE_TYPE")

If (o.ToString.ToUpper = "TABLE") Then
' El objeto es una tabla.
'
o = dr.Item("TABLE_NAME")

' Si el nombre contiene el carácter $, se
' trata del nombre de una hoja; en caso
' contrario, se trata del nombre de un rango.
'
' NOTA: Si el nombre de la hoja de cálculo contiene
' espacios en blanco (Mi Nombre Hoja), el nombre
' estará encerrado entre comillas simples
' ('Mi Nombre Hoja$')
'
Dim p As Int32 = o.ToString.IndexOf("$"c)

' Si se trata de un rango con nombre, y éstos
' no se incluyen, continuamos.
'
If p = -1 AndAlso Not includeRanges Then _
Continue For

' Si se trata de una hoja de cálculo, y éstas
' no se incluyen, continuamos.
'
If p <> -1 AndAlso Not includeSheets Then _
Continue For

ReDim Preserve tables(n)
tables(n) = o.ToString
n += 1
End If

Next dr

End If

Return tables

Catch ex As Exception

Return Nothing

Finally
' Cerramos la conexión si procede.
'
If cnn.State <> ConnectionState.Closed Then cnn.Close()
cnn = Nothing

End Try

End Function

Ahora, a la función simplemente la llamarías de la siguiente manera:

' Construimos la cadena de conexión.
'
Dim connString As String = _
"Provider=Microsoft.Jet.OLEDB.4.0;" & _
"Data Source=C:\Mis documentos\Libro1.xls;" & _
"Extended Properties='Excel 8.0;HDR=Yes'"

' Indicamos que deseamos recuperar tanto el nombre de
' las hojas de cálculo como el de los rangos de celdas
' con nombre.
'
Dim ranges() As String = _
GetRangesAndSheetsNames(connString, True, True)

ComboBox1.Items.Clear()

' Añadimos los elementos al control ComboBox.
'
For Each range As String In ranges
ComboBox1.Items.Add(range)
Next

ComboBox1.SelectedIndex = 0

¡Eso es todo! Adapta el ejemplo a tus necesidades.

Un saludo

Enrique Martínez
[MS MVP - VB]

Nota informativa: La información contenida en este mensaje, así como el
código fuente incluido en el mismo, se proporciona «COMO ESTÁ», sin
garantías de ninguna clase, y no otorga derecho alguno. Usted asume
cualquier riesgo al poner en práctica, utilizar o ejecutar lo recomendado o
sugerido en el presente mensaje.