Escribir nombre del libro y nombre de hoja

Hola chicos,

Mas opciones:

Ruta:
=INFO("directory")

Nombre Archivo:
=EXTRAE(CELDA("filename";A1);LARGO(INFO("directory"))+2;ENCONTRAR("]";CELDA("filename";A1))-LARGO(INFO("directory"))-2)

=EXTRAE(CELDA("filename";A1);ENCONTRAR("[";CELDA("filename";A1))+1;ENCONTRAR("]";CELDA("filename";A1))-ENCONTRAR("[";CELDA("filename";A1))-1)

Nombre Hoja:
=EXTRAE(CELDA("filename";$A$1);ENCONTRAR("]";CELDA("filename";$A$1);1)+1;LARGO(CELDA("filename";$A$1)))

si tambien quieres que tu formula este a prueba de una situacion un tanto particular de cuando el libro solo tiene una hoja y el nombre de esa es exactamente el mismo que el del libro, entonces usa la siguiente solucion un pelin mas larga:

=BUSCAR(REPETIR("z";255);SUSTITUIR(EXTRAE(CELDA("filename";$A$1);1+ENCONTRAR({"*"\"]"};SUSTITUIR(CELDA("filename";$A$1);"\";"*";LARGO(CELDA("filename";$A$1))-LARGO(SUSTITUIR(CELDA("filename";$A$1);"\";""))));255);".xls";""))

Notas:

1) Si no me equivoco, las formulas deberian funcionar en el Office en castellano aun usando los argumentos "filename" y "directory" (entonces las formulas serian compatibles con las versiones de Office en otros idiomas) De no ser asi, cambia "filename" por "nombrearchivo" y "directory" por "directorio".

2) Las formulas que usan la expresion CELDA("filename";A1), solo funcionarian en un archivo que ha sido guardado al menos una vez.

Saludos,
KL



"Francisco MTY" wrote in message news:%

Pega el codigo donde gustes

sub nombres()
Range("A1") = ActiveSheet.Name
Range("B1") = ActiveWorkbook.Name
end sub

Atte.
?T Francisco T?
http://groups.msn.com/ExcelVbaMacrosOffice
http://groups.msn.com/dadyboy

"El progreso debe ser un movimiento ordenado y racional hacia una meta
fija... y no un torbellino de direcciones falsas y encontradas."