¿como una celda puede tener zoom de pantalla completa ?

Mariangel,

Desconozco las posibilidades de MSO2003 en este aspecto, ya q tengo MSO97 y
2000. Sin embargo, asumiendo por un lado q no es posible hacer lo q pides
simplemente seleccionando la celda y dando al boton pantalla completa; y por
el otro lado q el zoom y la pantalla completa funcionan igual en las tres
versiones, me parecee q tendras al menos un par de problemas a resolver si
quisieras simular este efecto:
1) el zoom aumenta como max 400% (4x) (creo q forzosamente habra q
manipular el tamano de la celda y de su contenido)
2) como detectas la resolucion de pantalla vigente (si es q realmente es
necesario hay un codigo aqui http://j-walk.com/ss/excel/tips/tip06.htm)
2) como aseguras q las proporciones de la celda sean iguales a los de la
pantalla para q no se vean las celdas adyacentes (asumo tambien q no te
importa q se vean las barras de menus y herramientas de Excel) (se me ocurre
q la propiedad .VisibleRange del objeto Window en Visual Basic podria hacer
el truco).

Dicho lo anterior creo q una de las soluciones podrian ser los dos macros de
abajo asignados a unos botones o atajos.

Saludos,
KL

'--Inicio Codigo--
Sub AumentarCelda()
'En la Hoja2 se guardan los paramentros
'modificados para poder restablecer los
'mas tarde. Esta hoja puede estar oculta.
With Sheets("Hoja2")
.Cells(1, 1) = ActiveWindow.Zoom
.Cells(1, 2) = Rows(ActiveCell.Row).RowHeight
.Cells(1, 3) = Columns(ActiveCell.Column).ColumnWidth
.Cells(1, 4) = ActiveCell.Address
.Cells(1, 5) = ActiveCell.Font.Size
.Cells(1, 6) = ActiveCell.ShrinkToFit
End With

'Nos aseguramos q el zoom sea 100%.
ActiveWindow.Zoom = 100

'Procedemos a aumentar la celda activa.
With ActiveSheet
'Ajustamos su altura a la altura del
'area visible de la ventana de Excel
.Rows(ActiveCell.Row).RowHeight = _
ActiveWindow.VisibleRange.Height
'Ajustamos su ancho al ancho del area
'visible de la ventana de Excel y ademas
'convertimos la unidades correctamente.
.Columns(ActiveCell.Column).ColumnWidth = _
ActiveWindow.VisibleRange.Width / 5.27775709285874
With ActiveCell
'centramos la celda.
.Activate
'aumentamos la fuente al maximo.
.Font.Size = 409
'hacemos q la fuente se ajuste al
'tamano de la celda.
.ShrinkToFit = True
End With
End With
End Sub

Sub RestablecerCelda()
With Sheets("Hoja2")
'Por si la seleccion se habia desplazado
'de la celda aumentada, volvemos a activarla.
Range(.Cells(1, 4)).Activate
'Restablecemos el zoom inicial...
ActiveWindow.Zoom = .Cells(1, 1)
'...la altura de la fila,..
Rows(ActiveCell.Row).RowHeight = .Cells(1, 2)
'...el ancho de la columna...
Columns(ActiveCell.Column).ColumnWidth = .Cells(1, 3)
'...y las propiedades del texto.
ActiveCell.Font.Size = .Cells(1, 5)
ActiveCell.ShrinkToFit = .Cells(1, 6)
End With
End Sub
'--Fin Codigo--



"Mariangel" <Mariangel @discussions.microsoft.com> wrote in message
news:

Uso el office 2003, tengo un problema que resolver y es que quiero que la
celda que seleccione y le ponga "zoom de pantalla completa" simplemente se
adecue a toda la pantalla y no me muestre las casillas adyacentes a ella,
y
que no sea ajustando el tamano de celda, ya que una variacion de
resolucion
en el monitor hara que esto no se vea en pantalla completa (he ajustado
altos
y anchos de celda, y cuando cambio la resolucion, me aparecen las demas
celdas adyacentes)