como puedo juntar varias hojas de excel en una sola

Hola Isrrael,

Prueba el macro de abajo si las siguientes hipotesis son correctas:
1) La primera hoja es a donde se copia el resto de hojas
2) La fila [1] contiene encabezados en todas las hojas
3) Ningun registro puede tener la celda en la columna [A] vacia
4) Se tienen q consolidar todas las hojas del libro
5) Todas las hojas tienen el mismo orden y numero de columnas

Saludos,
KL

'Inicio Codigo
Sub test()
Dim h As Long, hFinal As Worksheet
Dim rngOrig As Range, rngDest As Range
Dim Fila As Long, UltFila As Long, UltCol As Integer

Application.ScreenUpdating = False
With ThisWorkbook
Set hFinal = .Worksheets(1)
UltCol = hFinal.Columns(256).End(xlToLeft).Column
For h = 2 To .Worksheets.Count
Fila = hFinal.Range("A65536").End(xlUp).Row
With Worksheets(h)
UltFila = .Range("A65536").End(xlUp).Row
Set rngOrig = .Range(.Cells(2, 1), _
.Cells(UltFila, UltCol))
End With
With hFinal
Set rngDest = .Range(.Cells(Fila + 1, 1), _
.Cells(Fila + UltFila - 1, UltCol))
End With

'Si hay q copiar formulas y formatos usa "Copy"
'rngOrig.Copy rngDest

'Si solo se quiere copiar constantes usa "="
rngDest.Value = rngOrig.Value
Next h
End With
Application.ScreenUpdating = True
End Sub
'Fin Codigo


"Isrrael" <pcpersonal> wrote in message
news:%

Hola a la comunidad,
¿cómo puedo hacer para poder juntar en promedio 30 hojas de excel con la
misma informacion, pero que terminan en distintas filas. Estoy tratando de
consolidarlas con la función consolidar, pero cada vez que agrego un
rango, me dice que no es válido.
alguien tendrá alguna idea?
saludos