C.U.I.L para Argentina

Te paso un mensaje viejo:

http://www.portalfox.com/article.php?sid#4

La generación de CUIT o CUIL la realizan unicamente el ANSSES, DGI, AFIP
y no se si algún otro organismo.

Yo hice alguna vez una rutina para generar el CUIT, pero hay ciertos
casos que el número generado, no es el mismo que el de los organismos
oficiales.

De todos modos te adjunto la rutina y tu la pruebas y ves si puedes
corregirla.

*--
* FUNCTION GenCUIT
*--
* Genera número de CUIT o CUIL
* USO: GenCUIT(<Caracter o Numerico>, <Tipo>)
* RETORNA: Caracter "99-99999999-9"
* PARAMETROS: tNro = Número para generar CUIT
* tcTipo = "S"ociedad, "H"ombre, "M"ujer
* AUTOR: LMG
*--
FUNCTION GenCUIT(tNro, tcTipo)

LOCAL lcPrefijo, lcCUIT, lnI, lcNro, lnDigito

IF EMPTY(tcTipo)
tcTipo = "@"
ENDIF

IF TYPE("tNro") = "C"
tNro = ALLTRIM(tNro)
ENDIF

lcNro=PADL(tNro,8,"0")

DO CASE
CASE tcTipo="S"
lcPrefijo="3033"
CASE tcTipo="H"
lcPrefijo="2023"
CASE tcTipo="M"
lcPrefijo="2723"
OTHER
lcPrefijo="909192"
ENDCASE
lnI=1
DO WHILE lnI < 10
lcCUIT = SUBS(lcPrefijo,lnI,2) + "-" + lcNro
lnSuma = VAL(SUBS(lcCUIT,11,1))*2 + VAL(SUBS(lcCUIT,10,1))*3 + ;
VAL(SUBS(lcCUIT,9,1))*4 + VAL(SUBS(lcCUIT,8,1))*5 + ;
VAL(SUBS(lcCUIT,7,1))*6 + VAL(SUBS(lcCUIT,6,1))*7 + ;
VAL(SUBS(lcCUIT,5,1))*2 + VAL(SUBS(lcCUIT,4,1))*3 + ;
VAL(SUBS(lcCUIT,2,1))*4 + VAL(SUBS(lcCUIT,1,1))*5
lnDigito = IIF(MOD(lnSuma,11)=0 ,0 , 11-MOD(lnSuma,11))
IF lnDigito < 10
lcCUIT = lcCuit + "-" + STR(lnDigito,1)
EXIT
ENDIF
lnI = lnI + 2
ENDDO
RETURN lcCUIT

ENDFUNC

*--


Luis María Guayán
Tucumán, Argentina
_________________________
http://www.PortalFox.com
Nada corre como un zorro
_________________________


El 10/05/2010 19:19, Dante Bravo escribió:

Buenas estimados foxeros, necesito saber de una función que, teniendo el
D.N.I. de Argentina, me genere el prefijo y el sufijo del C.U.I.L.
Desde ya, muchas gracias

Un fuerte abrazo

Dante Bravo
Tucumán - Argentina