Ayuda para crear una fórmula en una tabla

Omar,

En este caso podrias usar un trigger, puede ser INSTEAD OF ó AFTER.

Ejemplo:

use northwind
go

create table t (
colA int not null identity unique,
colB datetime,
colC varchar(25)
)
go

create trigger tr_set_colC_io_ins on t
instead of insert
as
set nocount on

insert into t (colB, colC)
select colB, case when datediff(day, colB, getdate()) = 0 then 'Baja' else
null end
from inserted
go

insert into t (colB) values ('20050221')
insert into t (colB) values ('20050222')
go

select * from t
go

drop trigger tr_set_colC_io_ins
go

create trigger tr_set_colC_ins on t
after insert
as
set nocount on

update
a
set
a.colC = case when datediff(day, a.colB, getdate()) = 0 then 'Baja' else
null end
from
t as a
inner join
inserted as i
on a.colA = i.colA
go

insert into t (colB) values ('20050223')
insert into t (colB) values ('20050221')
go

select * from t
go

drop table t
go


AMB


"Omar Flores" wrote:

Hola a todos, tengo una pequeña duda, tengo una tabla con la siguiente
estructura

Table
Id
Entrada
Fecha
Status

necesito comparar si el campo Fecha es mayor que la Fecha del día de hoy
(ToDay), si esto es verdadero Poner en el campo status "Baja"

Mi pregunta es, si esto es posible y si es así cómo sería la fórmula que
debo de aplicar para que me de este resultado.

Muchas gracias por su ayuda.