aumentar el numero de formato condicional

Martin,

Prueba el siguiente macro (aunque puede resultar un poco lento):

1) Haz clic derecho sobre la pestana con el nombre de la hoja (abajo de
todo)
2) Elige la opcion "Ver codigo". Se abrira el editor de VBA
3) En la ventana q aparecera a la derecha pega el codigo de abajo.
4) Modifica lo q haga falta en el codigo
5) Vuelve a la hoja y haz pruebas.

Saludos,
KL

'inicio codigo
Private Sub Worksheet_Change(ByVal Target As Range)
Dim MiRango As Range, c As Range

'Hacemos q solo funcione en el rango determinado
Set MiRango = Range("B2:T100")
If Intersect(Target, MiRango) Is Nothing Then _
Exit Sub
Application.ScreenUpdating = False
For Each c In MiRango
With c.Interior
Select Case c.Value
Case ""
.ColorIndex = xlNone 'transparente
Case Is < 201
.ColorIndex = 3 'rojo
.Pattern = xlSolid
Case 201 To 350
.ColorIndex = 6 'amarillo
.Pattern = xlSolid
Case 351 To 500
.ColorIndex = 4 'verde
.Pattern = xlSolid
Case Is > 500
.ColorIndex = 5 'azul
.Pattern = xlSolid
Case Else
'si el color por defecto q usas
'en la columna evaluada no es el
'transparente, cambia xlNone por el
'numero correspondiente.
.ColorIndex = xlNone 'transparente
End Select
End With
Next
End Sub
'fin codigo


"martin" wrote in message
news:

Buenos dias, y saludos a todos. Vengo otra vez a dar la vara con mi hoja
que tan amablemente me ayudo KL a resolver. Mi problema es que querria dar
4 formatos condicionales de color a cada columna y excel como parece ser
que todo el mundo sabia menos yo (he estado mirando san google) solo
permite 3. He intentado aplicar algunas lineas de codigo que he
encontrado,
pero no me funcionan. ¿podeis echarme un cable?

Lo que quiero es que en cada columna me salgan:

en rojo las celdas que contengan un valor menor de 200
en amarillo los que esten entre 201 y 350
en verde los que esten entre 351 y 500
en azul los que tengan valor superior a 500


La tabla tiene 20 columnas y 96 filas, si fuese posible querria que al
introducil datos en las filas sifuientes, adoptasen el formato
correspondiente segun su valor.


Gracias de antemano por la ayuda